EasyCo Release Notes

2.0.0.162

D3/NT

PLIP.CTRL CONFIG missing items

The CONFIG item that is shipped is missing a number of required configuration directives. In order to run 2.0.0.162 with D3/NT, you will need to add and delete several lines in the CONFIG item:

Add:  HOST TP=WIN
Add:  COMM TP=DLL
Add:  COMM PATH=C:/D3DEV
Add:  COMM ADDR=

Del:  DLL PATH=C:/D3DEV
This example assumes that the PLIP.DLL support file is loaded in the C:\D3DEV Windows directory. If you load the DLL in another directory, you will need to enter it's correct path here. You should note that the directory that you store the PLIP.DLL file in should be a simple directory that does not contain embedded spaces.

Flash/BASIC with D3/NT 7.2

PicLan-IP ships with all of it's BASIC code Flash-Compiled. With the release of D3/NT version 7.2, the format of FlashBASIC object code has changed so you will need to re-flash the PicLan-IP object code. You can create the following proc that will re-Flash all of the PicLan-IP code:

:ED MD PLIP-FLASH
001 PQ
002 HSSELECT DICT PLIP.BP WITH *A1 "CC"
003 STON
004 HBASIC PLIP.BP (OW<
005 P

If you have application level code that is being moved from D3/NT 7.1 to D3/NT 7.2, you should re-Flash your application object code as well.

Windows / Unix Platforms

Bug in PLHOST.IMPORT

A bug in the PLHOST.IMPORT subroutine was discovered. This bug occurs during PLZ compiles and IMPORT-WEB import operations from host drives. To fix this bug, re-compile the PLHOST.IMPORT subroutine with the following code:

      SUBROUTINE PLHOST.IMPORT(HOSTFILE,CONV,SRC)
*PIC-LAN
*
*MVBASE D3 UV UD
*PC
*N
*
*
*
*
      INCLUDE SYS.TYPE.INCLUDE
*
#IFN MVBASE|D3|UV|UD
   $Error - Invalid Target
#END
*
      INCLUDE PL.COMMON
      INCLUDE PL.COMMON.DEFS
      INCLUDE PL.DEFS
      INCLUDE PLIP.COMMON
      INCLUDE PLW.COMMON
*
      CALL PLU.HOSTDIR(HOSTFILE,FILE.PATH,FILE.NAME,FILE.EXT,SRC)
      IF SRC = '' THEN RETURN
*
      OPEN 'WWW.CTRL,LOCK' TO LOCK.FD ELSE CALL PLXX.STOP(201,'WWW.CTRL,LOCK')
      READVU DUMMY FROM LOCK.FD , 'HOST.IMPORT' , 1 ELSE NULL
*
      PL_HOSTOPEN FILE.HANDLE FROM FILE.PATH : FILE.NAME ELSE
         SRC = ''
         RELEASE LOCK.FD , 'HOST.IMPORT'
         RETURN
      END
*
      X = ''
      XX = ''
      XXX = ''
      EOF = NO
      LOOP UNTIL EOF DO
         BEGIN CASE
            CASE CONV = ''
               PL_HOSTREAD S FROM FILE.HANDLE ELSE
                  EOF = YES
               END
            CASE CONV = 'A'
               PL_HOSTREADA S FROM FILE.HANDLE ELSE
                  EOF = YES
               END
            CASE CONV = 'X'
               PL_HOSTREADX S FROM FILE.HANDLE ELSE
                  EOF = YES
               END
            CASE YES
               PL_HOSTCLOSE FILE.HANDLE ELSE NULL
               RETURN
         END CASE
         IF NOT(EOF) THEN
            IF S = '' THEN
               EOF = YES
            END ELSE
               IF LEN(XXX) > 200000 THEN
                  XX = XX : XXX
                  XXX = ''
                  IF LEN(XX) > 1000000 THEN
                     X = X : XX
                     XX = ''
                  END
               END
               XXX = XXX : S
            END
         END
      REPEAT
*
      IF CONV = '' OR CONV = 'A' THEN
         IF XXX[LEN(XXX),1] = CHAR(26) THEN
            XXX = XXX[1,LEN(XXX)-1]
         END
      END
*
      SRC = X : XX : XXX
*
      PL_HOSTCLOSE FILE.HANDLE ELSE NULL
*
      RELEASE LOCK.FD , 'HOST.IMPORT'
*
      RETURN

After the code is loaded (you should be able to cut-paste with most systems) you can compile it with:

PC PLIP.BP PLHOST.IMPORT